関数の宣言

これまでは Processing 言語が提供する関数を利用してきました。 同じように自分で関数を作成してそれを呼び出すことができます。 資料中では自分で作成した関数を自作関数と呼ぶことにします。 関数を作成することを関数の 宣言 と呼びます。

関数の宣言は以下の書式で行います。

戻り値の型 関数名(引数1の型 引数1の名前, 引数2の型 引数2の名前, 引数3の型 引数3の名前, ..., 引数nの型 引数nの名前) {
  処理の内容
}

関数名 は自作関数の名前です。処理内容が分かりやすい名前をつけるように心がけましょう。 戻り値の型 は関数が返す値の型を表します。 引数は、引数の型と引数の名前のペアをカンマ区切りで必要なだけ書きます。

関数から戻り値を返すためには return 文を使用します。 return 文で返される値は、関数の戻り値の型と一致している必要があります。

自作関数は、Processing 組み込みの関数と同じように呼び出すことができます。

以下は、関数を利用したプログラムの例です。

int add2(int x) {
  return x + 2;
}

float mean(float a, float b) {
  return (a + b) / 2;
}

boolean isEven(int x) {
  return x % 2 == 0;
}

String repeat(String s, int n) {
  String result = "";
  for (int i = 0; i < n; ++i) {
    result += s;
  }
  return result;
}

void setup() {
  noLoop();
}

void draw() {
  println(add2(2));
  println(add2(-5));

  println(mean(0.5, 4.8));
  println(mean(-3.25, 2.125));

  println(isEven(12345));
  println(isEven(678));

  println(repeat("hello", 5));
}

実行結果は以下のようになります。

4
-3
2.65
-0.5625
false
true
hellohellohellohellohello

関数の中身にはこれまで学修した逐次処理・条件分岐・繰り返しの処理を書くことができます。 戻り値と引数の型にも制限はなく、これまで学修した型を全て使用することができます。